Description: Use this script to query players by their steamids.


;/querysid <Steam Id>
alias querysid {
  .sockclose getsid | .sockopen getsid steamid.esportsea.com 80
  sockmark getsid $replace($1,:,$(%3A,0))
}
on *:sockopen:getsid:{
  sockwrite -n $sockname POST /?action=search&type=single&key=steam_id&query= $+ $sock($sockname).mark HTTP/1.1
  sockwrite -n $sockname Host: steamid.esportsea.com
  sockwrite -n $sockname Connection: Close
  sockwrite -n $sockname $crlf
}
on *:sockread:getsid:{
  var %data | sockread %data | tokenize 32 %data
  if $regex($1-,<tr onmouseover="style.backgroundColor='#e2e9eb';" onmouseout="style.backgroundColor='';">) {
    hinc -m $sockname count
  }

  if $hget($sockname,count) == 1 {
    if $regex($1-,<td><a href=".*" target="_blank">(.*)<\/a><\/td>) { hadd -m $sockname alias $regml(1) | hinc $sockname count | return }
  }
  elseif $hget($sockname,count) == 2 {
    if $regex($1-,<td>(.+)<\/td>) { hadd -m $sockname name $regml(1) | hinc $sockname count | return }
  }
  elseif $hget($sockname,count) == 3 {
    if $regex($1-,<td>(\d:\d:\d.+)<\/td>) { hadd -m $sockname sid $regml(1) | hinc $sockname count }
  }
  elseif $hget($sockname,count) == 4 {
    if $regex($1-,<a href="(.*)" title=".*" target="_blank">(.*)<\/a>) {
      hadd -m $sockname devision $regml(2) - $regml(1)
      hinc $sockname count | return
    }
  }
  elseif $hget($sockname,count) == 5 {
    if $regex($1-,<td>(.+)<\/td>) {
      hadd -m $sockname location $regml(1)
      hinc $sockname count | return
    }
  }
  elseif $hget($sockname,count) == 6 {
    if $regex($1-,<td><a href="(.*)" target="_blank">(.*)<\/a><\/td>) {
      hadd -m $sockname team $regml(2) - $regml(1)
      hinc $sockname count | return
    }
  }
  elseif $hget($sockname,count) == 7 {
    if $regex($1-,<td>(.+)<\/td>) {
      hadd -m $sockname tag $regml(1)
      hinc $sockname count | return
    }
  }
}
on *:sockclose:getsid:{  
  if ($hget($sockname,alias)) echo -a Alias: $v1
  if ($hget($sockname,name)) echo -a Name: $v1
  if ($hget($sockname,sid)) echo -a Steam ID: $v1
  if ($hget($sockname,devision)) echo -a Devision: $v1
  if ($hget($sockname,location)) echo -a Location: $v1
  if ($hget($sockname,team)) echo -a Team Name: $v1
  if ($hget($sockname,tag)) echo -a Tag: $v1
  .hfree -sw $sockname
}


Oops! You need to login or register before you can post a comment!