Description: Pretty /who

Here's a little dialog I made up to make using /who nicer.

Enter any search string in the box, enter the channel to check (# isn't needed) and mash on the scan button


To start, /chanscan



dialog chanscan {
  title "Channel Scanner"
  size -1 -1 166 106
  option dbu
  edit "", 1, 6 20 78 10
  edit "", 2, 6 40 78 10
  text "Search Line:", 4, 6 12 31 8
  text "Channel:", 5, 6 32 31 8
  button "Whois", 7, 6 68 37 8
  button "Clear", 10, 46 56 37 8
  button "Close", 11, 46 68 37 8, ok
  edit "Ready.", 12, 6 90 78 10, read
  text "Status:", 13, 6 82 19 8, right
  button "Scan", 15, 6 56 37 8
  list 3, 88 10 72 90, size
  box "Channel Scanner", 14, 2 2 162 102
}
on *:dialog:chanscan:sclick:7:{
  whois $did(chanscan,3).seltext $did(chanscan,3).seltext
}
on *:dialog:chanscan:sclick:10:{
  reset
}
on *:dialog:chanscan:sclick:15:{
  if ($did(chanscan,1) == $null) { did -r chanscan 12 | did -a chanscan 12 ERR: Search string required! | halt }
  if ($did(chanscan,2) == $null) { did -r chanscan 12 | did -a chanscan 12 ERR: Search target required! | halt }
  else {
    did -r chanscan 3
    set %scanfor $did(chanscan,1)
    startscan
  }
}
on *:dialog:chanscan:close:*:{
  unset %chanscan
}
alias chanscan {
  dialog -dmo chanscan chanscan
  set %chanscan 1
}
alias -l startscan {
  if ($left($did(chanscan,2),1) != $chr(35)) {
    who $chr(35) $+ $did(chanscan,2)
  }
  else {
    who $did(chanscan,2)
  }
}
alias -l reset {
  did -r chanscan 1,2,3
  did -r chanscan 12
  did -a chanscan 12 Ready.
}
raw 352:*:{
  if (!%chanscan) { return }
  else {
    did -r chanscan 12
    did -a chanscan 12 Scanning $2 $+ ...
    if (%scanfor isin $1-) {
      did -a chanscan 3 $6
    }
  }
}
raw 315:*:{
  if (!%chanscan) { return }
  else {
    did -r chanscan 12
    did -a chanscan 12 Ready.
  }
}


use raw 354, you can get more info :)

Oops! You need to login or register before you can post a comment!